bat如何延时执行指定命令？

首先bat延迟指的是就是执行一条命令后延迟一段时间再进行下一条命令。在cmd 下或批处理中，常使用以下四种方法进行时间延迟：

1、利用ping命令延时。
示例1：

@echo off
echo 延时前：%time%
ping /n 3 127.0.0.1 >nul
echo 延时后：%time%
pause

2、利用for命令延时。

示例2：

@echo off
echo 延时前：%time%
for /l %%i in (1,1,5000) do echo %%i>nul
echo 延时后：%time%
pause

3、利用vbs延迟函数，精确度毫秒，误差1000毫秒内。

示例3：

@echo off
echo %time%
call :delay 5000
echo %time%
pause
exit

:delay
echo WScript.Sleep %1>delay.vbs
CScript //B delay.vbs
del delay.vbs
goto :eof

4、仅用批处理命令实现任意时间延迟，精确度10毫秒，误差50毫秒内仅用批处理命令就可以实现延迟操作。

示例4：

@echo off
set /p delay=请输入需延迟的毫秒数：
set TotalTime=0
set NowTime=%time%
::读取起始时间，时间格式为：13:01:05.95
echo 程序开始时间：%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::读取起始时间的分钟数
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::将起始时间的秒数转为毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 读取现在时间的分钟数
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::将现在时间的秒数转为毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序结束时间：%time%
echo 设定延迟时间：%delay%毫秒
echo 实际延迟时间：%TotalTime%毫秒
pause

希望以上几种方法能让你圆满的解决问题！