怎样在excel一个表中输入一个人的名字能显示出另一个工作表中这个人的某项信息

用vlookup函数。
VLOOKUP 函数
本文介绍 Microsoft Excel 中 VLOOKUP 函数 函数:函数是预先编写的公式，可以对一个或多个值执行运算，并返回一个或多个值。函数可以简化和缩短工作表中的公式，尤其在用公式执行很长或复杂的计算时。的公式语法和用法。
说明
您可以使用 VLOOKUP 函数搜索某个单元格区域 （区域:工作表上的两个或多个单元格。区域中的单元格可以相邻或不相邻。）的第一列，然后返回该区域相同行上任何单元格中的值。 例如，假设区域 A2:C10 中包含雇员列表。 雇员的 ID 号存储在该区域的第一列，如下图所示。

如果知道雇员的 ID 号，则可以使用 VLOOKUP 函数返回该雇员所在的部门或其姓名。 若要获取 38 号雇员的姓名，可以使用公式 =VLOOKUP(38, A2:C10, 3, FALSE)。 此公式将搜索区域 A2:C10 的第一列中的值 38，然后返回该区域同一行中第三列包含的值作为查询值（“黄雅玲”）。
VLOOKUP 中的 V 参数表示垂直方向。 当比较值位于需要查找的数据左边的一列时，可以使用 VLOOKUP 而不是 HLOOKUP。
语法
VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup])
VLOOKUP 函数语法具有下列参数 参数:为操作、事件、方法、属性、函数或过程提供信息的值。：
lookup_value 必需。 要在表格或区域的第一列中搜索的值。 lookup_value 参数可以是值或引用。 如果为 lookup_value 参数提供的值小于 table_array 参数第一列中的最小值，则 VLOOKUP 将返回错误值 #N/A。
table_array 必需。 包含数据的单元格区域。 可以使用对区域（例如，A2:D8）或区域名称的引用。 table_array 第一列中的值是由 lookup_value 搜索的值。 这些值可以是文本、数字或逻辑值。 文本不区分大小写。
col_index_num 必需。 table_array 参数中必须返回的匹配值的列号。 col_index_num 参数为 1 时，返回 table_array 第一列中的值；col_index_num 为 2 时，返回 table_array 第二列中的值，依此类推。
如果 col_index_num 参数：
小于 1，则 VLOOKUP 返回 错误值 #REF!。
大于 table_array 的列数，则 VLOOKUP 返回。 错误值 #REF!。
range_lookup 可选。 一个逻辑值，指定希望 VLOOKUP 查找精确匹配值还是近似匹配值：
如果 range_lookup 为 TRUE 或被省略，则返回精确匹配值或近似匹配值。 如果找不到精确匹配值，则返回小于 lookup_value 的最大值。
重要信息 如果 range_lookup 为 TRUE 或被省略，则必须按升序排列 table_array 第一列中的值；否则，VLOOKUP 可能无法返回正确的值。
有关详细信息，请参阅对区域或表中的数据进行排序。
如果 range_lookup 为 FALSE，则不需要对 table_array 第一列中的值进行排序。
如果 range_lookup 参数为 FALSE，VLOOKUP 将只查找精确匹配值。 如果 table_array 的第一列中有两个或更多值与 lookup_value 匹配，则使用第一个找到的值。 如果找不到精确匹配值，则返回错误值 #N/A。
说明
在 table_array 第一列中搜索文本值时，请确保 table_array 第一列中的数据没有前导空格、尾部空格、直引号（' 或 "）与弯引号（‘或“）不一致或非打印字符。 否则，VLOOKUP 可能返回不正确或意外的值。
有关详细信息，请参阅 CLEAN 函数和 TRIM 函数。
在搜索数字或日期值时，请确保 table_array 第一列中的数据未存储为文本值。 否则，VLOOKUP 可能返回不正确或意外的值。
如果 range_lookup 为 FALSE 且 lookup_value 为文本，则可以在 lookup_value 中使用通配符 （问号 (?) 和星号 (*)） 。 问号匹配任意单个字符；星号匹配任意一串字符。 如果要查找实际的问号或星号，请在该字符前键入波形符 (~)。

示例
复制下表中的示例数据，然后将其粘贴到新 Excel 工作簿的 A1 单元格中。 为使公式显示结果，请选中它们，按 F2，然后按 Enter。 如果需要，您可以调整列宽以查看所有数据。
密度 粘度 温度
0.457 3.55 500
0.525 3.25 400
0.606 2.93 300
0.675 2.75 250
0.746 2.57 200
0.835 2.38 150
0.946 2.17 100
1.09 1.95 50
1.29 1.71 0
公式 说明 结果
=VLOOKUP(1,A2:C10,2) 使用近似匹配搜索 A 列中的值 1，在 A 列中找到小于等于 1 的最大值 0.946，然后返回同一行中 B 列的值。 2.17
=VLOOKUP(1,A2:C10,3,TRUE) 使用近似匹配搜索 A 列中的值 1，在 A 列中找到小于等于 1 的最大值 0.946，然后返回同一行中 C 列的值。 100
=VLOOKUP(0.7,A2:C10,3,FALSE) 使用精确匹配在 A 列中搜索值 0.7。 因为 A 列中没有精确匹配的值，所以返回一个错误值。 #N/A
=VLOOKUP(0.1,A2:C10,2,TRUE) 使用近似匹配在 A 列中搜索值 0.1。 因为 0.1 小于 A 列中最小的值，所以返回一个错误值。 #N/A
=VLOOKUP(2,A2:C10,2,TRUE) 使用近似匹配搜索 A 列中的值 2，在 A 列中找到小于等于 2 的最大值 1.29，然后返回同一行中 B 列的值。 1.71
示例 2
货品 ID 货品 成本 涨幅
ST-340 童车 $145.67 30%
BI-567 围嘴 $3.56 40%
DI-328 尿布 $21.45 35%
WI-989 柔湿纸巾 $5.12 40%
AS-469 吸出器 $2.56 45%
公式 说明 结果
= VLOOKUP("DI-328", A2:D6, 3, FALSE) * (1 + VLOOKUP("DI-328", A2:D6, 4, FALSE)) 涨幅加上成本，计算尿布的零售价。 $28.96
= (VLOOKUP("WI-989", A2:D6, 3, FALSE) * (1 + VLOOKUP("WI-989", A2:D6, 4, FALSE))) * (1 - 20%) 零售价减去指定折扣，计算柔湿纸巾的销售价格。 $5.73
= IF(VLOOKUP(A2, A2:D6, 3, FALSE) >= 20, "涨幅为 " & 100 * VLOOKUP(A2, A2:D6, 4, FALSE) &"%", "成本低于 $20.00") 如果某一货品的成本大于或等于 $20.00，则显示字符串“涨幅为 nn%”；否则，显示字符串“成本低于 $20.00”。 涨幅为 30%
= IF(VLOOKUP(A3, A2:D6, 3, FALSE) >= 20, "涨幅为: " & 100 * VLOOKUP(A3, A2:D6, 4, FALSE) &"%", "成本为 $" & VLOOKUP(A3, A2:D6, 3, FALSE)) 如果某一货品的成本大于或等于 ￥20.00，则显示字符串“涨幅为 nn%”；否则，显示字符串“成本为 $n.nn”。 成本为 $3.56
示例 3
ID 姓 名 职务 出生日期
1 李 小明 销售代表 12/8/1968
2 林 彩瑜 销售 副总裁 2/19/1952
3 王 志东 销售代表 8/30/1963
4 潘 钢 销售代表 9/19/1958
5 林 锋 销售经理 3/4/1955
6 苏 术平 销售代表 7/2/1963
公式 说明 结果
=INT(YEARFRAC(DATE(2004,6,30), VLOOKUP(5,A2:E7,5, FALSE), 1)) 针对 2004 财政年度，查找 ID 为 5 的员工的年龄。 使用 YEARFRAC 函数，以此财政年度的结束日期减去出生日期，然后使用 INT 函数将结果以整数形式显示。 49
=IF(ISNA(VLOOKUP(5,A2:E7,2,FALSE)) = TRUE, "未找到员工", VLOOKUP(5,A2:E7,2,FALSE)) 如果有 ID 为 5 的员工，则显示该员工的姓氏；否则，显示消息“未找到员工”。

当 VLOOKUP 函数返回错误值 #N/A 时，ISNA 函数返回值 TRUE。 林
=IF(ISNA(VLOOKUP(15,A3:E8,2,FALSE)) = TRUE, "未找到员工", VLOOKUP(15,A3:E8,2,FALSE)) 如果有 ID 为 15 的员工，则显示该员工的姓氏；否则，显示消息“未找到员工”。

当 VLOOKUP 函数返回错误值 #NA 时，ISNA 函数返回值 TRUE。 未找到员工
=VLOOKUP(4,A2:E7,3,FALSE) & " " & VLOOKUP(4,A2:E7,2,FALSE) & "是" & VLOOKUP(4,A2:E7,4,FALSE) 对于 ID 为 4 的员工，将三个单元格的值连接为一个完整的句子。 潘钢是销售代表。

表1中B2=VLOOKUP(A1,Sheet2!A:B,2,0)
A1是表1中A1单元格
Sheet2!A:B,是表2中A和B两列
2,从匹配项到想要数据的列数,如A到B,是2,
0,匹配方式

用Vlookup函数。
其实你可以点击excel的 fx按钮，查看该函数的帮助。
VLOOKUP(a, b, c, [d])

a，是你要找的值，你的这个例子中，就是表1的A列
b ，是你在什么范围内要找a，b一般是一个区域。你要找的a的值，应包含在b区域的第一列。
c，数值，如果你在b中找到了a，c表示你要返回b中对应的a数值所在行的第几列的数值。这个数值跟Excel自身的ABCD列没有关系，如果b是从B2---C5，那么如果c=2,则表示你要去的C列中的某个值。
d，这个是可选。默认不写这个参数，表示的是true. 如果你想准确查找，就应该用false
另外，如果用false，那么如果你b中第一列没有你要找的值a，则会返回错误。
如果你用true，则要求B的第一列必须按照从小到大排序，而且如果b的第一列没有你要找的值a，则会返回b中一个不超过a的最大值所在行的指定列的数值，这很可能就不是准确查找了。

在表一中的B1单元格输入,然后往下拉就可以了.
=VLOOKUP(A1,Sheet2!A:B,2,0)

vloopup函数
vlookup(根据要查找的值，查找区域，查找的列数，查找类型（精确查找0，模糊查找1）)